Code: Select all
File: c:\logfiles\log.*
Look for: String errormessage
In fact, "Text Log" test method does not process all the files. If you specify the wildcards in the name of the file, the 1st matched file will be checked.GijsbertVanOeveren wrote:The result is that I only get a warning when the errormessage is found in all logfiles instead of after a single occurrence.
Lets clarify it a bit, because I do not completely understand your needs. Do you mean, you want to check all files and fire alert when the criterium is experienced in only one file (if two of more files match the criteria we do not fire alert) or when the criterium is experienced in at least one file?GijsbertVanOeveren wrote:Is there a possibility to monitor all files and fire a warning if the criterium is experienced in just 1 of the files?
Code: Select all
@echo off
IF "%1"=="" GOTO HELP
IF "%2"=="" GOTO HELP
SET VAR1=
SET TMPVAR=
FOR %%f IN (%1) DO FOR /F "tokens=1 delims= " %%e in ('type %%f ^| find "%2"') DO CALL file_processcheck.bat %%f
IF "%VAR1%"=="" GOTO NONEFOUND
ECHO ScriptRes:Bad:Errors found in files: %VAR1%
SET VAR1=
SET TMPVAR=
GOTO END
:NONEFOUND
ECHO No instances found
GOTO END
:HELP
ECHO Usage: file_runcheck {filepath to search, may include wildcard} {word to search for}
GOTO END
:END
Code: Select all
@echo off
IF "%TMPVAR%"=="" GOTO GETFIRST
IF "%1"=="%TMPVAR%" GOTO GETNEXT
GOTO :GETSECOND
:GETFIRST
SET VAR1=%1
GOTO :GETNEXT
:GETSECOND
SET VAR1=%VAR1%, %1
GOTO :GETNEXT
:GETNEXT
SET TMPVAR=%1
Great job!GijsbertVanOeveren wrote:I have managed to create batch files to check the appropriate files.
Below is a transcript of the two files.
Correct. You should use "echo" command. You have properly write the following command: ECHO ScriptRes:Bad:Errors found in files: %VAR1%GijsbertVanOeveren wrote:You mention though that the script should write to the 'stdout', which to my knowledge is a unix of linux thing. How is that on a Windows system? Just an echo from the script?
Code: Select all
...
:NONEFOUND
ECHO ScriptRes:Ok:No instances found
GOTO END
:HELP
ECHO ScriptRes:Unknown:Usage: file_runcheck {filepath to search, may include wildcard} {word to search for}
GOTO END
:END In most cases it uses the oldest file.GijsbertVanOeveren wrote:One more question about the 'TextLog' test method: you mention that it checks the first matched file when using wildcards. What will it see as 'first matched': oldest or newest or maybe another criterium?
Code: Select all
@echo off
:--------------------------------------------------------
:: Jump to Help if not all parameters have been given
IF "%1"=="" GOTO HELP
IF "%2"=="" GOTO HELP
:--------------------------------------------------------
:--------------------------------------------------------
:: Initiate variables
:--------------------------------------------------------
SET ConcatFiles=
SET ProcessFile=
SET PreviousFile=
SET ProcessingResult=
:--------------------------------------------------------
:--------------------------------------------------------
:: Loop through the files (%1) and search for the string (%2)
:--------------------------------------------------------
FOR %%f IN (%1) DO FOR /F "tokens=1 delims= " %%e IN ('type %%f ^| find "%2"') DO (
SET ProcessFile=%%f
CALL :CHECKITEMS
)
:--------------------------------------------------------
:--------------------------------------------------------
:: Looping is done, now jump to build the report
:--------------------------------------------------------
GOTO :BUILDREPORT
:--------------------------------------------------------
:--------------------------------------------------------
:: This section is called from the loop
:--------------------------------------------------------
:CHECKITEMS
IF "%PreviousFile%"=="" GOTO GETFIRST
IF "%ProcessFile%"=="%PreviousFile%" GOTO TRYNEXT
GOTO :GETSECOND
:GETFIRST
SET ConcatFiles=%ProcessFile%
GOTO :TRYNEXT
:GETSECOND
SET ConcatFiles=%ConcatFiles%, %ProcessFile%
GOTO :TRYNEXT
:TRYNEXT
SET PreviousFile=%ProcessFile%
GOTO :EOF
:--------------------------------------------------------
:--------------------------------------------------------
:: Build the report
:BUILDREPORT
IF "%ConcatFiles%"=="" (
SET ProcessingResult=Ok:No instances found
) ELSE (
SET ProcessingResult=Bad:Errors found in files: %ConcatFiles%
)
ECHO ScriptRes:%ProcessingResult%
:--------------------------------------------------------
:--------------------------------------------------------
:: Clear the variables that have been used
SET ConcatFiles=
SET ProcessFile=
SET PreviousFile=
SET ProcessingResult=
GOTO END
:--------------------------------------------------------
:--------------------------------------------------------
:HELP
ECHO Usage: integrated_file_runcheck {filepath to search, may include wildcard} {word to search for}
GOTO END
:--------------------------------------------------------
:--------------------------------------------------------
:END
:--------------------------------------------------------
You are right. HostMonitor is unable to invoke the script, that is stored in "Script Manager", from another script. Of course, it is possible to call certain script from filesystem directly (e.g. "call C:\temp\some_script.bat"), but it in not pretty convenient and not much flexible.GijsbertVanOeveren wrote:Since I wanted to have the two batchfiles in just one, I had to change the code. In HostMonitor I could not find how to have one batch script cal another one, so I made one back script out of it.
Code: Select all
:HELP
ECHO ScriptRes:Unknown:Usage: file_runcheck {filepath to search, may include wildcard} {word to search for}
GOTO END Code: Select all
@echo off
:--------------------------------------------------------
:: Jump to Help if not all parameters have been given
IF "%1"=="" GOTO HELP
IF "%2"=="" GOTO HELP
:--------------------------------------------------------
:--------------------------------------------------------
:: Initiate variables
:--------------------------------------------------------
SET SearchString=
SET ConcatFiles=
SET ProcessFile=
SET PreviousFile=
SET ProcessingResult=
SET TmpDrivePath=
SET TmpFile=
:: Check if a string of two words is given to search for
IF "%3"=="" (
SET SearchString=%2
) ELSE (
SET SearchString=%2 %3
)
:--------------------------------------------------------
:--------------------------------------------------------
:: Loop through the files (%1) and search for the string (%SearchString%)
:--------------------------------------------------------
FOR %%f IN (%1) DO FOR /F "tokens=1 delims= " %%e IN ('type %%f ^| find "%SearchString%"') DO (
SET ProcessFile=%%f
SET TmpDrivePath=%%~dpf
SET TmpFile=%%~nxf
CALL :CHECKITEMS
)
:--------------------------------------------------------
:--------------------------------------------------------
:: Looping is done, now jump to build the report
:--------------------------------------------------------
GOTO :MAKEREPORT
:--------------------------------------------------------
:--------------------------------------------------------
:: This section is called from the loop
:--------------------------------------------------------
:CHECKITEMS
IF "%PreviousFile%"=="" GOTO GETFIRST
IF "%ProcessFile%"=="%PreviousFile%" GOTO TRYNEXT
GOTO :GETSECOND
:GETFIRST
COPY %ProcessFile% %TmpDrivePath%CHECKED_%TmpFile%_CHECKED > NUL
SET ConcatFiles=%ProcessFile%
GOTO :TRYNEXT
:GETSECOND
COPY %ProcessFile% %TmpDrivePath%CHECKED_%TmpFile%_CHECKED > NUL
DEL %PreviousFile%
SET ConcatFiles=%ConcatFiles%, %ProcessFile%
GOTO :TRYNEXT
:TRYNEXT
SET PreviousFile=%ProcessFile%
GOTO :EOF
:--------------------------------------------------------
:--------------------------------------------------------
:: Build the report
:MAKEREPORT
IF "%ConcatFiles%"=="" (
SET ProcessingResult=Ok:No instances found
) ELSE (
SET ProcessingResult=Bad:Errors found in files: %ConcatFiles%
)
ECHO ScriptRes:%ProcessingResult%
:--------------------------------------------------------
:--------------------------------------------------------
:: Clear the variables that have been used and delete the last processed file
IF NOT "%ProcessFile%"=="" DEL %ProcessFile%
SET SearchString=
SET ConcatFiles=
SET ProcessFile=
SET PreviousFile=
SET ProcessingResult=
SET TmpDrivePath=
SET TmpFile=
GOTO END
:--------------------------------------------------------
:--------------------------------------------------------
:HELP
ECHO ScriptRes:Unknown:Usage: integrated_file_runcheck {filepath to search, may include wildcard} {word to search for}
GOTO END
:--------------------------------------------------------
:--------------------------------------------------------
:END
:--------------------------------------------------------Great job, Gijsbert. Wel done! I can allow myself to encourage you to post this awesome script into the "Library" branch of our forum:GijsbertVanOeveren wrote:I implemented this in the HostMonitor as a Shell Script Test and it works as planned.
Wow! 8 words. In fact, I think you may pass the several (8 or more) words as a second parameter. You just should wrap the second parameter into the quotation marks (""). For instance:GijsbertVanOeveren wrote:I also changed a little bit in the code which now allows search strings up to 8 words
Code: Select all
Params: C:\*.txt "error message multi words"You are welcome.GijsbertVanOeveren wrote:Thanks for your help and encouragements!
Code: Select all
SET TMP1=%2
ECHO %TMP1:~0,1%Code: Select all
SET TMP1=%2
SET TMP2=%TMP1:~0,1%Code: Select all
IF !%TMP2%!==!"! SET QUOT=Quotations UsedCode: Select all
IF NOT "%QUOT%"=="Quotations Used" (
{use method 1}
) ELSE (
{use method 2}
)Code: Select all
@echo off
SET TMP1=%1
SET TMP2=%~1
echo Parameter: %TMP1%
Call :STRLEN %TMP1%
SET LenVar1=%RESULT%
ECHO Length: %LenVar1%
SET RESULT=
echo Parameter: %TMP2%
Call :STRLEN %TMP2%
SET LenVar2=%RESULT%
ECHO Length: %LenVar2%
SET RESULT=
SET /A NewVal=%LenVar1%-%LenVar2%
ECHO Difference in length: %NewVal%
IF %NewVal%==2 (
ECHO The String: %TMP1% has quotation marks!
) ELSE (
ECHO The String: %TMP1% has NO quotation marks.
)
:STRLEN
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
SET STR=%1 & SET STR=!STR:~0,-1!
SET LEN=0
SET POS=8192
:STRLEN_LOOP
SET /A POS /= 2
IF NOT "!STR!" == "" (
IF NOT "!STR:~%POS%,1!" == "" (
SET /A LEN += %POS% + 1
SET STR=!STR:~%POS%!
SET STR=!STR:~1!
)
GOTO :STRLEN_LOOP
)
ENDLOCAL & SET RESULT=%LEN%
GOTO :EOFActually, I do not. In fact, this is a difficult matter. Handling quotation marks in scripts is a real headache. So, I do not think it worth to continue with this script because it becomes too complex and dificult to understand. Let's leave your first script as the base script. What do you think?GijsbertVanOeveren wrote:Do you have any simpler suggestions?
